## 11.27c.Cymr.txt

# General definitions (common to all scripts)
define PIArCons [h|ɦ|H|s|z|k|p|t|k h|p h|t h|b|d|g|g ɦ|b ɦ|d ɦ|m|n|l|r|u̯|s|š|ć|ć h|j́ |j́ ɦ|č|č h|ǰ|ǰ ɦ] ;
define RepeatAll [?|i̯|u̯|ū́|j́|ṓ|ī́|ė̃|ā́|ė́|r̥|ŕ̥|r̃|l̥|ĺ̥|ǝ̄|ɑ́]* ;
define Stop [k|p|t|ć|č|c|g|b|d|ḱ|ǵ|j́|j|ǰ|q|ǥ] ;
define Glottal [h|ɦ|H] ;
define Front [e|ē|é|ḗ|i|ī|í|ī́] ;
define Vowel [a|ā|á|ā́|e|ē|é|ḗ|i|ī|í|ī́|o|ō|ó|ṓ|u|ū|ú|ū|ū́] ;
define Resonant [i|í|u|ũ|û|ú|l|r|m|n] ;
define Consonant ["-"|k|p|t|k h|p h|t h|g|b|d|g ɦ|b ɦ|d ɦ|m|n|l|r|i̯|u̯|y|w|s|ñ|ṣ|ś|t s|č] ;
define Ruki [r|r̥|ŕ̥|u|ū|ú|ū́|k|i|ī|í|ī́] ;
define Tremulant [r|r̥|ŕ̥] ;
define Velar [k|k h|g|g ɦ] ;
define Affricate [ć|j́|č|ǰ|c|j] ;
define Voiced [b|d|g|ǰ] ;
define Voicedasp [b ɦ|d ɦ|g ɦ|ǰ ɦ] ;
define C ["-"|k|p|t|h|g|b|d|ɦ|m|n|l|r|i̯|u̯|y|w|s|ñ|ṣ|ś|č|c|ć|j|j́] ;
define Liquid [l|l̥|r|r̥] ;
define Dental [n|s|t|t h|d|d ɦ] ;
define Delta [g|b|d|ǰ|j́] ;
define Retroflex [ṇ | ṣ | ṭ | ṭ h | ḍ | ḍ ɦ] ;
define SchwaPhon [ ɦ | h | k | p | t | k h | p h | t h | g | b | d | g ɦ | b ɦ | d ɦ | m | n | l | r | s | ć | j́ | č | ǰ] ;

define Rɑe›ɑa e -> a || ɑ _ ; # PIE *ɑe → ɑa | Møller's rule for PIE *ɑe | (SPIE §2.2.5.3)
define Rɑé›ɑá é -> á || ɑ _ ; # PIE *ɑé → ɑá | Møller's rule for PIE *aé | (SPIE §2.2.5.3)
define Reɑ›aɑ e -> a || _ ɑ ; # PIE *eɑ → aɑ | De Saussure's rule for PIE *eɑ | (SPIE §2.2.7)
define Réɑ›áɑ é -> á || _ ɑ ; # PIE *éɑ → áɑ | De Saussure's rule for PIE *éɑ | (SPIE §2.2.7)
define Rɑē›ɑā ē -> ā || ɑ _ ; # PIE *ɑē → ɑā | Pyysalo's rule for PIE *ɑē | (SPIE §2.2.10)
define Rēɑ›āɑ ē -> ā || _ ɑ ; # PIE *ēɑ → āɑ | Pyysalo's rule for PIE *ēɑ | (SPIE §2.2.10)
define Rɑḗ›ɑā́ ḗ -> ā́ || ɑ _ ; # PIE *ɑḗ → ɑā́ | Pyysalo's rule for PIE *ɑḗ | (SPIE §2.2.10)
define Rḗɑ›ā́ɑ ḗ -> ā́ || _ ɑ ; # PIE *ḗɑ → ā́ɑ | Pyysalo's rule for PIE *ḗɑ | (SPIE §2.2.10)
define Rɑ́i›íi ɑ́ i -> í i ; # PIE *ɑ́i → íi | Assimilation of *ɑ́ and *i | (SPIE §3.2.6)
define Riɑ́›ií ɑ́ -> í || i _ ; # PIE *iɑ́ → ií | Assimilation of *i and *ɑ́ | (SPIE §3.2.6)
define Rɑ́u›úu ɑ́ u -> ú u ; # PIE *ɑ́u → úu | Assimilation of *ɑ́ and *u | (SPIE §3.2.3)
define Ruɑ́›uú ɑ́ -> ú || u _ ; # PIE *uɑ́ → uú | Assimilation of *u and *ɑ́ | (SPIE §3.2.3)
define Rɑ́Hi›íHi ɑ́ -> í || _ Glottal i ; # PIE *ɑ́ḫi → íḫi | Distant assimilation of *ɑ́ and *i | (SPIE §3.2.6)
define RiHɑ́›iHí ɑ́ -> í || i Glottal _ ; # PIE *iḫɑ́ → iḫí | Distant assimilation of *i and *ɑ́ | (SPIE §3.2.6)
define Rɑ́Hu›úHu ɑ́ -> ú || _ Glottal u ; # PIE *ɑ́ḫu → úḫu | Distant assimilation of *ɑ́ and *u | (SPIE §3.2.3)
define RuHɑ́›uHú ɑ́ -> ú || u Glottal _ ; # PIE *uḫɑ́ → uḫú | Distant assimilation of *u and *ɑ́ | (SPIE §3.2.3)
define Rɑ́i̯›íi̯ ɑ́ i̯ -> í́ i̯ ; # PIE *ɑ́i̯ → íi̯ | Assimilation of *ɑ́ and *i̯ | (SPIE §3.2.6)
define Ri̯ɑ́›i̯í i̯ ɑ́ -> i̯ í ; # PIE *i̯ɑ́ → i̯í | Assimilation of *i̯ and *ɑ́ | (SPIE §3.2.6) 
define Rɑ́u̯›úu̯ ɑ́ u̯ -> ú u̯ ; # PIE *ɑ́u̯ → úu̯ | Assimilation of *ɑ́ and *u̯ | (SPIE §3.2.3)
define Ru̯ɑ́›u̯ú u̯ ɑ́ -> u̯ ú ; # PIE *u̯ɑ́ → u̯ú | Assimilation of *u̯ and ɑ́ | (SPIE §3.2.3)
define Rɑ́Hi̯›íHi̯ ɑ́ -> í || _ Glottal i̯ ; # PIE *ɑ́ḫi̯ → íḫi̯ | Distant assimilation of *ɑ́ and *i̯ | (SPIE §3.2.6)
define Ri̯Hɑ́›i̯Hí ɑ́ -> í || i̯ Glottal _ ; # PIE *i̯ḫɑ́ → i̯ḫí | Distant assimilation of *i̯ and *ɑ́ | (SPIE §3.2.6)
define Rɑ́Hu̯›úHu̯ ɑ́ -> ú || _ Glottal u̯ ; # PIE *ɑ́ḫu̯ → úḫu̯ | Distant assimilation of *ɑ́ and *u̯ | (SPIE §3.2.3)
define Ru̯Hɑ́›u̯Hú ɑ́ -> ú || u̯ Glottal _ ; # PIE *u̯ḫɑ́ → u̯ḫú | Distant assimilation of *u̯ and *ɑ́ | (SPIE §3.2.3)
define Rɑ́›á ɑ́ -> á ; # PIE *ɑ́ → á | Fronting of *ɑ́ into á | (SPIE §2.2.4)
define Rɑ›0 ɑ -> 0 ; # PIE *ɑ → Ø | Loss of *ɑ | (SPIE §2.2.4)
define RkI›ḱ k i -> ḱ , k i̯ -> ḱ ; # PIE *ki/i̯ → k | Palatovelarization of *ki/i̯ into *ḱ | (SPIE §4.8.4)
define RkhI›ḱh k h i -> ḱ h , k h i̯ -> ḱ h ; # PIE *khi/i̯ → kh | Palatovelarization of *khi/i̯ into ḱh | (SPIE §4.8.4)
define RkIh›ḱh k i h -> ḱ h , ḱ i̯ h -> ḱ h ; # PIE *ki/i̯h → kh | Palatovelarization of *ki/i̯h into ḱh | (SPIE §4.8.4)
define RgI›ǵ g i -> ǵ , g i̯ -> ǵ ; # PIE *gi/i̯ → g | Palatovelarization of *gi/i̯ into ǵ | (SPIE §4.8.4)
define RgɦI›ǵɦ g ɦ i -> ǵ ɦ , g ɦ i̯ -> ǵ ɦ ; # PIE *gɦi/i̯ → gɦ | Palatovelarization of *gɦi/i̯ into ǵ | (SPIE §4.8.4)
define RgIɦ›ǵɦ g i ɦ -> ǵ ɦ , g i̯ ɦ -> ǵ ɦ ; # PIE *gi/i̯ɦ → gɦ | Palatovelarization of *gi/i̯ɦ into ǵ | (SPIE §4.8.4)
define Rɦ›0 ɦ -> 0 || .#. | \Stop _ ; # PIE *ɦ → Ø | Loss of segmental *ɦ | (SPIE §2.1.4)
define Rh›0 h -> 0 || .#. | \Stop _ ; # PIE *h → Ø | Loss of segmental *h | (SPIE §2.1.4)
define Rr̥›r r̥ -> r ; # PIE *r̥ → r | Desyllafibication of r̥ after loss of h/ɦ | (SPIE §XX)
define Ríi›ī́ í i -> ī́ ; # *íi → ī́ | Contraction of í and i |
define Rií›ī́ i í -> ī́ ; # *ií → ī́ | Contraction of i and í |
define Rii›ī i i -> ī ; # *ii → ī | Contraction of i and i |
define Rúu›ū́ ú u -> ū́ ; # *úu → ū́ | Contraction of ú and u |
define Ruú›ū́ u ú -> ū́ ; # *uú → ū́ | Contraction of u and ú |
define Ruu›ū u u -> ū ; # *uu → ū | Contraction of u and u |
define RāRC›aRC ā -> a || _ Resonant Consonant ; # *āRC → aRC | Osthoff’s Law for *āRC | (SPIE §2.5.8)
define Rā́RC›áRC ā́ -> á || _ Resonant Consonant ; # *ā́RC → áRC | Osthoff’s Law for *ā́RC | (SPIE §2.5.8)
define RēRC›eRC ē -> e || _ Resonant Consonant ; # *ēRC → eRC | Osthoff’s Law for *ēRC | (SPIE §2.5.8)
define RḗRC›éRC ḗ -> é || _ Resonant Consonant ; # *ḗRC → éRC | Osthoff’s Law for *ḗRC | (SPIE §2.5.8)
define RīRC›iRC ī -> i || _ Resonant Consonant ; # *īRC → iRC | Osthoff’s Law for *īRC | (SPIE §2.5.8)
define Rī́RC›íRC ī́ -> í || _ Resonant Consonant ; # *ī́RC → íRC | Osthoff’s Law for *ī́RC | (SPIE §2.5.8)
define RōRC›oRC ō -> o || _ Resonant Consonant ; # *ōRC → oRC | Osthoff’s Law for *ōRC | (SPIE §2.5.8)
define RṓRC›óRC ṓ -> ó || _ Resonant Consonant ; # *ṓRC → óRC | Osthoff’s Law for *ṓRC | (SPIE §2.5.8)
define RūRC›uRC ū -> u || _ Resonant Consonant ; # *ūRC → uRC | Osthoff’s Law for *ūRC | (SPIE §2.5.8)
define Rū́RC›úRC ū́ -> ú || _ Resonant Consonant ; # *ū́RC → úRC | Osthoff’s Law for *ū́RC | (SPIE §2.5.8)
define Rḱ›k ḱ -> k ; # PIE *ḱ → k | Depalatalization of Centum *ḱ | (SPIE §4.8.4)
define Rǵ›g ǵ -> g ; # PIE *ǵ → g | Depalatalization of Centum *ǵ | (SPIE §4.8.4)
define Rln›ll l n -> l l ; # PIE *ln → ll | Assimilation of PIE *ln into ll |
define RCHs›Cs Glottal -> 0 || Stop _ s ; # CHs → Cs | Loss of *h between stop and *s |
define Rkh›k k h -> k ; # *kh → k | Loss of *h in tenues aspirata *kh |
define Rph›p p h -> p ; # *ph → p | Loss of *h in tenuis aspirata *ph |
define Rth›t t h -> t ; # *th → t | Loss of *h in tenuis aspirata *th |
define Rp›h p -> h ; # *p → h | Change of *p into h |
define RkU›p k[u | u̯] -> p ; # *ku/u̯ → p | Bilabialization of labiovelar q into p |
define RgU›b g[u | u̯] -> b ; # *gu/u̯ → b | Bilabialization of labiovelar into b | (SPIE §4.8.3)
define RgɦU›gɦ u | u̯ -> 0 || g ɦ _ ; # *gɦU → gɦ | Delabialization of labiovelar gɦu/u̯ | (SPIE §4.8.3)
define Rbɦ›b b ɦ -> b ; # *bɦ → b | Loss of *ɦ in media aspirata *bɦ | (SPIE §4.8.1.5)
define Rdɦ›d d ɦ -> d ; # *dɦ → d | Loss of *ɦ in media aspirata *dɦ | (SPIE §4.8.1.5)
define Rgɦ›g g ɦ -> g ; # *gɦ → g | Loss of *ɦ in media aspirata *gɦ | (SPIE §4.8.1.5)
define Rrs›rr r s -> r r ; # *rs → rr | Assimilation of *rs into rr |
define Rndn›nn d -> 0 || n _ n ; # *ndn → nn | Loss of d between n and n |
define Rh›0 h -> 0 || .#. | \Stop _ ; # PIE *h → Ø | Loss of segmental *h | (SPIE §2.1.4)
define Rē›ī ē -> ī ; # *ē → ī | Change of *ē into ī |
define Rō›ā ō -> ā ; # PIE *ō → ā | Change of *ō into ā |
define Rei›ē ei -> ē ; # *ei → ē | Monophthongization of *ei into ē |
define Rou›ō o u -> ō ; # *ou → ō | Monophthongization of *ou into ō |
define Ruo›u̯o u o -> u̯ o || .#. _ ; # *uo- → u̯o- | Change of *uo- into u̯o- |
define Rnb›mb n b -> m b ; # *nb → mb | Change of *n into m before b |
define Rmb›mm b -> m || m _ ; # mb →  mm | Assimilation of m and b |
define Rds›s d s -> s ; # *ds → s | Change of ds into s |
define Rsd›ðð s d -> ð ð ; # sd → ðð | Change of sd to ðð |
define Rā›aw ā -> aw || _ \["-"] ; # *ā -› aw | Change of ā into aw |
define Rā›a ā -> a ; # *ā → a | Change of *ā into a |
define Rari›eir a r i -> e i r ; # *ari → eir | Epenthesis of *i | 
define Rm›f m -> f || Vowel _ Vowel ; # VmV -› VfV | Lenition of m into f |
define R=a›=0 a -> 0 || _ .#. ; # *-a → Ø | Loss of root-final -a |
define R=o›=0 o -> 0 || _ .#. ; # *-o → -Ø | Loss of root-final *o |
define R=i›=0 i -> 0 || _ .#. ; # *-i → Ø | Loss of root-final -i |
define Rðð›tt ð ð -> t t ; # ðð → tt | Devoicing of geminate ðð to tt |
define RsV=hV= s -> h || .#. _ Vowel ; # sV- -› hV- | Change of sV- into hV- |
define Rū́›ī́ ū́ -> ī́ ; # *ū́ → ī́ | Change of *ū́ into ī́ |
define R=nn›=n n n -> n || _ .#. ; # *-nn → -n | Simplification of root-final geminate *nn- |
define R=ss›=s s s -> s || _ .#. ; -ss -> -s | Degemination of ss in root-final |
define Reti›edi e t i -> e d i ; # *eti → edi | Voicing of t between vowels |
define Rsr›r sr -> r || _ \[.#.] ; # *sr → r | Loss of *s before r |
define Rī́›ī ī́ -> ī ; # *ī́ → ī | Loss/Absence of accent |
define Rī›i ī -> i ; # *ī → i | Change of *ī into i |
define Ru̯=›gu= u̯ -> g u || .#. _ ; # * u̯- → gu- | Change of root-initial u̯- into gu- |
define Rtt›th t t -> t h ; # tt -› th | Lenition of tt -> th |
define Rkt›th k t -> t h ; # *kt → th | Loss of k before t and lenition |
define Rl=›ll= l -> l l || .#. _ ; # *l- → ll- | Gemination of root-initial *l- |
define Rsk›sg k -> g || s _ ; # *sk → sg | Change of sk to sg |
define Rthy›thi t h i̯ -> t h i ; # *i̯- → i- | Orthographic change of *i̯ into i |
define Rk›c k -> c ; # *k → c | Orthographic change of *k into c |
define Ri̯›i i̯ -> i ; # *i̯ → i | Orthographic change of i̯ into i |
define Ru̯›w u̯ -> w ; # *u̯ → w | Orthographic change of *u̯ into w |
define Rcs›x c s -> x ; # *cs → x | Change of *cs into x |

chain Rɑe›ɑa, Rɑé›ɑá, Reɑ›aɑ, Réɑ›áɑ, Rɑē›ɑā, Rēɑ›āɑ, Rɑḗ›ɑā́, Rḗɑ›ā́ɑ, Rɑ́i›íi, Riɑ́›ií, Rɑ́u›úu, Ruɑ́›uú, Rɑ́Hi›íHi, RiHɑ́›iHí, Rɑ́Hu›úHu, RuHɑ́›uHú, Rɑ́i̯›íi̯, Ri̯ɑ́›i̯í, Rɑ́u̯›úu̯, Ru̯ɑ́›u̯ú, Rɑ́Hi̯›íHi̯, Ri̯Hɑ́›i̯Hí, Rɑ́Hu̯›úHu̯, Ru̯Hɑ́›u̯Hú, Rɑ́›á, Rɑ›0, RkI›ḱ, RkhI›ḱh, RkIh›ḱh, RgI›ǵ, RgɦI›ǵɦ, RgIɦ›ǵɦ, Rɦ›0, Rh›0, Rr̥›r, Ríi›ī́, Rií›ī́, Rii›ī, Rúu›ū́, Ruú›ū́, Ruu›ū, RāRC›aRC, Rā́RC›áRC, RēRC›eRC, RḗRC›éRC, RīRC›iRC, Rī́RC›íRC, RōRC›oRC, RṓRC›óRC, RūRC›uRC, Rū́RC›úRC, Rḱ›k, Rǵ›g, Rln›ll, RCHs›Cs, Rkh›k, Rph›p, Rth›t, Rp›h, RkU›p, RgU›b, RgɦU›gɦ, Rbɦ›b, Rdɦ›d, Rgɦ›g, Rrs›rr, Rndn›nn, Rh›0, Rē›ī, Rō›ā, Rei›ē, Rou›ō, Ruo›u̯o, Rnb›mb, Rmb›mm, Rds›s, Rsd›ðð, Rā›aw, Rā›a, Rari›eir, Rm›f, R=a›=0, R=o›=0, R=i›=0, Rðð›tt, RsV=hV=, Rū́›ī́, R=nn›=n, R=ss›=s, Reti›edi, Rsr›r, Rī́›ī, Rī›i, Ru̯=›gu=, Rtt›th, Rkt›th, Rl=›ll=, Rsk›sg, Rthy›thi, Rk›c , Ri̯›i, Ru̯›w, Rcs›x;